Starting/Stoping Windows Services with WMI from External Tools (VS2005)

Mon, 27 Nov 2006 19:33:55 GMT

A menudo sucede que para compilar una solución es necesario parar algunos servicio (este es el caso en que estamos desarrollando un servicio o compilando alguna .dll referenciada por este) o bien que nuestra aplicación dependa de que se encuentren corriendo algunos de ellos en particular como por ejemplo el SQL Server (MSSQLSERVER), Message Queuing, BizTalk Server Application Service, etc.

También es cierto que comenzar o detener estos desde la consola de servicios es algo un poco tedioso sobre todo si es una tarea que se realiza muy a menudo.

Mi solución a esto es un Script que mediante WMI arranque o detenga los servicios que necesitamos. Este script recibe por parámetro desde la linea de comandos /start para indicar que debe comenzar los servicios o /stop para detener los servicios. Es importante notar que vamos a trabajar sobre los servicios de un servidor remoto y no sobre nuestra PC por lo que vamos a ver que en el código tenemos hardcodeado los nombres del server, user y password.

Un detalle a tener en cuenta es que a la hora de detener un servicio mediante el método StopService() de la clase WMI_Service, este puede retornar un "Dependent Services Running" indicando que existen servicios corriendo lo cuales dependen del servicio que se intenta detener por lo que la solución es parar todos los servicios dependientes en forma recursiva y la ..... Listo.

Ahora, ya que venimos con la preocupación de ahorrarnos trabajo tedioso, sería estúpido tener que ir a la linea de comandos para escribir: C:\>cscript Services.vbs [/start | /stop]

La solución nos la da Martín Melchior; las External Tools. Les paso como queda el registro de Windows con los cambios:

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\VisualStudio\8.0\External Tools]
"ToolTitle8"="Start Services"
"ToolCmd8"="cscript.exe "
"ToolArg8"="services.vbs /start"
"ToolDir8"="C:\\Documents and Settings\\lontivero\\Desktop\\"
"ToolSourceKey8"=""
"ToolOpt8"=dword:0000001a
"ToolTitle9"="Stop Services"
"ToolCmd9"="cscript.exe"
"ToolArg9"="services.vbs /stop"
"ToolDir9"="C:\\Documents and Settings\\lontivero\\Desktop\\"
"ToolSourceKey9"=""
"ToolOpt9"=dword:0000001a

Ok, ya la tenemos como external tools de Visual Studio 2005, así que ¿estamos felices?. Claro que no!! Recuerden que para ser buen desarrollador hay que ser VAGO por eso vamos a ponerles una teclas de acceso rápido. Propongo Ctrl+S, Ctrl+U (Services Up) y Ctrl+S, Ctrl+Down (Services Down). Ahora si..

El Script:

Dim objWMIService, arrServiceNames, i, arrErrorCodes


Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator") 
Set objWMIService = objSWbemLocator.ConnectServer("computerName", "root\CIMV2", "username", "password") 


arrServiceNames = Array(_
 "BTSSvc$BiztalkServerApplication", _
 "ENTSSO", _
 "MSSQLSERVER" _
)

arrErrorCodes   = Array( _
 "(succeeded)",_
 "Request not supported",_
 "Access Denied",_
 "Dependent Services Running",_
 "Invalid Service Control",_
 "Service cannot accept control",_
 "Service not active",_
 "Request timeout",_
 "Unknown failure",_
 "Service executable file not found",_
 "Service Already Running",_
 "Service database locked",_
 "Missing dependent service",_
 "Dependent service failed",_
 "Service disabled",_
 "Incorrect authentication",_
 "Service is being removed",_
 "No execution thread available",_
 "Circular dependencies",_
 "Duplicate service name already running",_
 "Invalid character in the service name",_
 "Invalid parameters passed to the service",_
 "Invalid or underprivileged service account",_
 "Service already exists",_
 "Service paused"_
)

For i = 0 To UBound(arrServiceNames)
   SwitchServiceStatus arrServiceNames(i)
Next
WScript.StdOut.WriteLine "Ready."


Sub SwitchServiceStatus(strServiceName)
   Dim objShare, objOutParams, strMethodName, objArgs, intError

   Set objShare = objWMIService.Get("Win32_Service.Name='" & strServiceName & "'") 
   If objShare Is Nothing Then
      WScript.Stdout.WriteLine "There isn't a '" & strServiceName & "' service."
   Else
      WScript.Stdout.Write "'" & objShare.Caption & "'   "
      strMethodName = IIf(WScript.Arguments(0)="/start","StartService","StopService")

      If strMethodName = "StopService" Then
         SwitchOffDependencies strServiceName
      End If

      Set objOutParams = objWMIService.ExecMethod(_
                            "Win32_Service.Name='" & _
                            strServiceName & "'", _
                            CStr(strMethodName)_
                         )
      
      If objOutParams.ReturnValue <> 0 Then
         WScript.Stdout.WriteLine arrErrorCodes(objOutParams.ReturnValue)
      End If
   End If
End Sub


Sub SwitchOffDependencies(strServiceName)
   Dim colServiceList, objService

   Set colServiceList = objWMIService.ExecQuery(_
        "Associators of " &_
        "{Win32_Service.Name='" & strServiceName & "'}" &_
        " Where " &_
        "AssocClass=Win32_DependentService " & _
        "Role=Antecedent" )

   For Each objService in colServiceList
      WScript.Stdout.WriteLine "Dependent service: " & objService.Name & "   State: " & objService.State
      If objService.State <> "Stoped" Then
         WScript.Stdout.WriteLine "Stopping dependent service " & objService.Name
         SwitchServiceStatus objService.Name    
      End If
   Next
End Sub

Function IIf(bExpr, exprTrue, exprFalse)
   If bExpr Then
      IIf = exprTrue
   Else
      IIf = exprFalse
   End If
End Function

Lucas Ontivero: Scripting

Starting/Stoping Windows Services with WMI from External Tools (VS2005)